CMake - how to set multiple compile definitions for target executable?

Question

I'm trying to set multiple compile definitions for one of the executables I'm trying to compile in CMake (in order to activate macros used for debugging). Here's what I tried:

add_executable (trie_io_test trie_io_test.c trie.c word_list.c)
    set_target_properties(
            trie_io_test
            PROPERTIES
            COMPILE_DEFINITIONS UNIT_TESTING=1)
    set_target_properties(
            trie_io_test
            PROPERTIES
            COMPILE_DEFINITIONS IO_TEST=1)

Unfortunately this causes only the IO_TEST to be defined.

I also tried the following:

add_executable (trie_io_test trie_io_test.c trie.c word_list.c)
    set_target_properties(
            trie_io_test
            PROPERTIES
            COMPILE_DEFINITIONS UNIT_TESTING=1 IO_TEST=1)

But this, on the other hand, causes CMake error.

How to set both of these definitions for the executable I'm trying to build?

Fraser · Accepted Answer · 2015-05-30 13:25:38Z

71

You want target_compile_definitions instead of set_target_properties:

target_compile_definitions(trie_io_test PRIVATE UNIT_TESTING=1 IO_TEST=1)

answered May 30, 2015 at 13:25

Fraser

79.1k23 gold badges255 silver badges225 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Fraser Over a year ago

I linked to the docs in my answer, but it's really only useful for libraries rather than exes. Libs can define their compile flags as PRIVATE, PUBLIC or INTERFACE. PRIVATE basically means the flags are only applied to this library. PUBLIC and INTERFACE flags are also applied to any target which links to it (i.e. its dependees); the difference between these two being that INTERFACE flags aren't applied to the library itself - only its dependees.

qiubit Over a year ago

Thanks, for the reference, this is an answer to my question "What does PRIVATE mean in this case?" which I deleted, because I saw that there was a link to documentation after asking the question.

Jay Over a year ago

PRIVATE adds the property just to this target. INTERFACE adds the property to targets that link to this target. PUBLIC acts as both PRIVATE and INTERFACE because it adds the property to both this target and to targets that link to this target.

einpoklum Over a year ago

This appends the compile definitions, right? That is, we can use this command repeatedly with more definitions later on, right?

curiousdannii Over a year ago

@einpoklum Yes, you can call it multiple times.

|

Chen · Accepted Answer · 2019-11-22 05:23:03Z

2

I find this can work for you:

add_executable (trie_io_test trie_io_test.c trie.c word_list.c)
set_target_properties(
    trie_io_test
    PROPERTIES
    COMPILE_DEFINITIONS UNIT_TESTING=1
    COMPILE_DEFINITIONS IO_TEST=1
   )

Just by adding another COMPILE_DEFINITIONS :P

edited Nov 22, 2019 at 5:23

answered Nov 22, 2019 at 3:49

Chen

1122 silver badges8 bronze badges

2 Comments

Virus_7 Over a year ago

It didn't work for me when using with set_source_files_properties(). The second overwrites the first.

daedsidog Over a year ago

Does not work. One overwrites the other.

Gert-Jan de Vos · Accepted Answer · 2023-10-10 12:54:51Z

1

This does work:

add_executable (trie_io_test trie_io_test.c trie.c word_list.c)
set_target_properties(
    trie_io_test
    PROPERTIES
    COMPILE_DEFINITIONS "UNIT_TESTING=1;IO_TEST=1"
   )

No clue why this makes a difference. It was my understanding that in cmake, white space separated lists are equivalent to semicolon separated strings.

answered Oct 10, 2023 at 12:54

Gert-Jan de Vos

111 bronze badge

3 Comments

Jeremy Caney Over a year ago

Isn’t this effectively just validating the previous, very similar answer? If not, can you highlight the difference? I see that the code is slightly different, but it’s unclear as a reader if that difference is critical here. Can you edit your answer to provide clarification?

cp.engr Over a year ago

@JeremyCaney this is the only answer with the semicolon.

klaus triendl Oct 12 at 18:37

The CMake documentation states that "The COMPILE_DEFINITIONS property may be set to a semicolon-separated list of preprocessor definitions using the syntax VAR or VAR=value.". That's why it works and it can be useful if properties are set on a single source file using set_source_files_properties().

Collectives™ on Stack Overflow

CMake - how to set multiple compile definitions for target executable?

3 Answers 3

7 Comments

2 Comments

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

7 Comments

2 Comments

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related