Plot[2x, {x,0,4}];
Plot[x^2, {x,4,8}];
How do I merge these two graphs into one?
$\begingroup$
$\endgroup$
2
2 Answers
$\begingroup$
$\endgroup$
1
Here's a way that may serve you also for other purposes:
p[x_, left_, right_] := HeavisideTheta[x - left] HeavisideTheta[right - x]
Plot[{2 x p[x, 0, 4], x^2 p[x, 4, 8]}, {x, 0, 8}]
Another example:
tab = Table[x^(1/n) p[x, n, n + 1], {n, 1, 10}];
Plot[tab, {x, 0, 8}, PlotStyle -> Thick]
-
$\begingroup$ The zeroed part still gets plotted though. $\endgroup$lineage– lineage2024-05-25 15:56:58 +00:00Commented May 25, 2024 at 15:56
$\begingroup$
$\endgroup$
2
Update: Using thicker lines to make the difference between various methods visible:
Plot[{ConditionalExpression[2 x, 0 <= x < 4], ConditionalExpression[x^2, 4 < x <= 8]}, {x, 0, 8},
BaseStyle -> Thickness[.02]]
Plot[{Piecewise[{{2 x, 0<=x<4}}, Indeterminate],
Piecewise[{{x^2, 4<x<= 8}}, Indeterminate]}, {x, 0, 8}, BaseStyle -> Thickness[.02]]
ct = ConditionalExpression[#, #2] & @@@ Table[{x^(1/n), n < x <= n + 1}, {n, 10}];
Plot[ct, {x, 0, 8}, PlotStyle -> Thickness[.02]]
pw = Piecewise[{{#, #2}}, Indeterminate] & @@@ Table[{x^(1/n), n < x <= n + 1}, {n, 10}];
Plot[pw, {x, 0, 8}, PlotStyle -> Thickness[.02]]
whereas,
p[x_, left_, right_] := HeavisideTheta[x - left] HeavisideTheta[right - x]
Plot[{2 x p[x, 0, 4], x^2 p[x, 4, 8]}, {x, 0, 8}, BaseStyle -> Thickness[.02]]
tab = Table[x^(1/n) p[x, n, n + 1], {n, 1, 10}];
Plot[tab, {x, 0, 8}, PlotStyle -> Thickness[.02]]
Similarly, using Boole in place of HeavisideTheta:
Plot[{2 x Boole[0 <= x <= 4], x^2 Boole[4 < x <= 8]}, {x, 0, 8}, BaseStyle -> Thickness[.02]]
-
$\begingroup$ If single-color plot is acceptable,
Piecewiseapproach can be simplified toPlot[Piecewise[{{2 x, 0 <= x < 4}, {x^2, 4 < x <= 8}}, Indeterminate], {x, 0, 8}]$\endgroup$Bob Hanlon– Bob Hanlon2014-10-26 18:12:06 +00:00Commented Oct 26, 2014 at 18:12 -
$\begingroup$ @Bob, multiple colors is in fact the reason for the clunkier multiple
Piecewises. $\endgroup$kglr– kglr2014-10-26 18:41:41 +00:00Commented Oct 26, 2014 at 18:41
Show[ Plot[2 x, {x, 0, 4}], Plot[x^2, {x, 4, 8}], PlotRange -> All]? $\endgroup$